Simple Conduction Example

Introduction

This tutorial was created using ANSYS 7.0 to solve a simple conduction problem.

The Simple Conduction Example is constrained as shown in the following figure. Thermal conductivity (k) of the material is 10 W/m*C and the block is assumed to be infinitely long.

---

Preprocessing: Defining the Problem

1. Give example a Title
2. Open preprocessor menuANSYS Main Menu > Preprocessor
   /PREP7
3. Create geometryPreprocessor > Modeling > Create > Areas > Rectangle > By 2 Corners > X=0, Y=0, Width=1, Height=1
   BLC4,0,0,1,1
4. Define the Type of Element
Preprocessor > Element Type > Add/Edit/Delete... > click 'Add' > Select Thermal Mass Solid, Quad 4Node 55
ET,1,PLANE55For this example, we will use PLANE55 (Thermal Solid, Quad 4node 55). This element has 4 nodes and a single DOF (temperature) at each node. PLANE55 can only be used for 2 dimensional steady-state or transient thermal analysis.


5. Element Material Properties
Preprocessor > Material Props > Material Models > Thermal > Conductivity > Isotropic > KXX = 10 (Thermal conductivity)
MP,KXX,1,10

6. Mesh Size
Preprocessor > Meshing > Size Cntrls > ManualSize > Areas > All Areas > 0.05
AESIZE,ALL,0.05

7. Mesh
Preprocessor > Meshing > Mesh > Areas > Free > Pick All
AMESH,ALL

---

Solution Phase: Assigning Loads and Solving

1. Define Analysis Type
Solution > Analysis Type > New Analysis > Steady-State
ANTYPE,0

2. Apply Constraints
For thermal problems, constraints can be in the form of Temperature, Heat Flow, Convection, Heat Flux, Heat Generation, or Radiation. In this example, all 4 sides of the block have fixed temperatures.



• Solution > Define Loads > Apply
  Note that all of the -Structural- options cannot be selected. This is due to the type of element (PLANE55) selected.
• Thermal > Temperature > On Nodes
• Click the Box option (shown below) and draw a box around the nodes on the top line.
  The following window will appear:
  
  
• Fill the window in as shown to constrain the side to a constant temperature of 500
• Using the same method, constrain the remaining 3 sides to a constant value of 100Orange triangles in the graphics window indicate the temperature contraints.


3. Solve the System
Solution > Solve > Current LS
SOLVE

---

Postprocessing: Viewing the Results

1. Results Using ANSYS
Plot Temperature
General Postproc > Plot Results > Contour Plot > Nodal Solu ... > DOF solution, Temperature TEMP
Note that due to the manner in which the boundary contitions were applied, the top corners are held at a temperature of 100. Recall that the nodes on the top of the plate were constrained first, followed by the side and bottom constraints. The top corner nodes were therefore first constrained at 500C, then 'overwritten' when the side constraints were applied. Decreasing the mesh size can minimize this effect, however, one must be aware of the limitations in the results at the corners.

ANSYS Command Listing

/title, Simple Conduction Example
/PREP7

! define geometry

length=1.0
height=1.0
blc4,0,0,length, height  ! area - one corner, then width and height

! mesh 2D areas

ET,1, PLANE55   ! Thermal element only
MP,KXX,1,10   ! 10 W/mC
ESIZE,length/20   ! number of element sub-divisions/side
AMESH,ALL

FINISH
/SOLU

ANTYPE,0   ! STEADY-STATE THERMAL ANALYSIS

! fixed temp BC's
NSEL,S,LOC,Y,height  ! select nodes on top with y=height
D,ALL,TEMP,500   ! apply fixed temp of 500C
NSEL,ALL
NSEL,S,LOC,X,0   ! select nodes on three sides
NSEL,A,LOC,X,length
NSEL,A,LOC,Y,0
D,ALL,TEMP,100   ! apply fixed temp of 100C
NSEL,ALL

SOLVE
FINISH

/POST1
PLNSOL,TEMP,,0,   ! contour plot of temperatures